Lisp程序设计错误处理的技巧

admin · 发表于 2024-4-6 16:40:32

;|
Gxl-ErrStaSys -> Gxl-ErrEnd ;只针对系统变量的恢复
Gxl-ErrSta -> Gxl-ErrEnd ;系统变量+函数+编组
Gxl-ErrStaNrm -> Gxl-ErrEndNrm ;只针对自定义常量的恢复
|;
Lisp程序设计错误处理的技巧@Gu_xl，由Kucha梳理 (源自博客:http://guxl.mjtd.com/?p=14)
任何程序在运行中都可能不完全会按照程序设计者预想的方式去运行，程序运行中会出现各种意想不到的情况,
AutoLisp提供的标准错误处理函数*error*,仅能告诉你程序运行有了错误,但不能对错误进行善后处理。
这对于一个优秀的程序来说,是不能忍受的,为此,我们应当用自定义的错误处理函数来改善这种情况,使程序在出现任何错误情况下都能正确处理！
//一、在程序内设置局部自定义错误处理函数
AutoLisp提供内部提供了一个标准的自定义错误处理函数:(*error* string)
当AutoLisp程序运行出错时, *error* 函数值不为空
AutoCAD会传递给 *error* 函数的参数 string 一个错误信息字符串值,并自动执行 *error* 函数。
根据这个错误处理运行机制,我们可以根据自己的需要,对错误处理函数 *error* 进行自定义。
;;;例1:自定义如下错误处理函数:
(defun *error* (Msg)
(princ "error:")
(princ Msg);打印错误信息
(princ)
)
当Lisp程序运行出错时,系统会自动调用 *error* 函数,打印出错误处理信息。
但是这个错误处理函数几乎没有什么用,该错误处理函数仅仅是对错误信息进行了输出,没有对可能出现的错误进行任何处理
这可不是我们想要的程序,我们需要对 *error* 函数内容根据程序处理的需要进行定制！
;;;例2:下面是一个绘制三角形的例子,程序目的是在图上选取三点,自动绘制三角形,。
(defun C:TT (/ Old_CMD Old_OSM p1 p2 P3)
(setq Old_CMD (getvar "cmdecho"));保存系统变量cmdecho值
(setvar "cmdecho" 0);关闭命令行的回显提示
(setq Old_OSM (getvar "osmode"));保存系统变量osmode值
(setvar "osmode" 0);关闭捕捉模式
(setq p1 (getpoint "\n输入第一点: ")
P2 (getpoint "\n输入第二点: ")
P3 (getpoint "\n输入第三点: ")
)
(vl-cmdf "_.pline" p1 p2 p3 "c")
(setvar "cmdecho" Old_CMD);恢复cmdecho系统变量
(setvar "osmode" Old_OSM);恢复osmode系统变量
(princ)
)
在程序正常运行的情况下,程序会在绘制完三角形后自动恢复系统变量"osmode"、" Old_CMD",
但是在图面选取点时,按下ESC键,或某个点输入为空,会导致程序出错
后面的恢复系统变量值的代码则不会执行,程序关闭了捕捉模式,我们不得不手动来重新设置捕捉方式。
为此,我们在程序的开始自定义一个错误处理函数 *error* ,在 *error* 函数内添加恢复系统变量"osmode"、" Old_CMD"的代码
在程序运行出错时自动调用 *error* 函数, *error* 函数内恢复系统变量"osmode"、" Old_CMD"的代码自动运行
这便达到了我们对程序错误处理的要求！示例代码如下:
(defun C:TT (/ *error* Old_OSM Old_CMD p1 p2 P3)
(defun *error* (Msg)
(setvar "cmdecho" Old_CMD);恢复cmdecho系统变量
(setvar "osmode" Old_OSM);恢复osmode系统变量
(princ "error: ")
(princ Msg);打印错误信息
(princ)
)
;;以下为主程序内容
(setq Old_CMD (getvar "cmdecho"));保存系统变量cmdecho值
(setvar "cmdecho" 0);关闭命令行的回显提示
(setq Old_OSM (getvar "osmode"));保存系统变量osmode值
(setvar "osmode" 0);关闭捕捉模式
(setq p1 (getpoint "\n输入第一点: ")
P2 (getpoint "\n输入第二点: ")
P3 (getpoint "\n输入第三点: ")
)
(vl-cmdf "_.pline" p1 p2 p3 "c")
(setvar "cmdecho" Old_CMD);恢复cmdecho系统变量
(setvar "osmode" Old_OSM);恢复osmode系统变量
(princ)
)
//二、通用错误处理函数的处理技巧
请注意,在上面例2的程序中,我们是将 *error* 函数声明为局部变量,则该错误处理仅在test函数范围内有效！
这样我们就需要在每个程序里都要添加类似的错误处理代码,其实大部分程序的错误处理代码都类似
如果在每个程序里都添加相同的代码,是一件很讨厌的事儿,会导致代码越来越长
为此,我们可以做一个通用错误处理函数,以后仅需要调用该函数即可,无需再写出长长的一串代码！
;;;例3:自定义通用错误处理初始化函数
(defun Gxl-ErrStaSys (SysLst / SysNam SysVar)
;|(Gxl-ErrStaSys SysLst) 初始化*error*
功能: 保存 SysLst 给定的系统变量值,并按表给定的系统变量值设置系统变量
参数:
SysLst 系统变量及其设置值列表例如: '("osmode" 0 "cmdecho" 0 "cecolor" "1")
|;·
(setq *OldEr* *error*);储存*error*函数
(defun *error* (Msg / SysNam SysVar)
(if *Old_SysVar* ;储存的系统变量值列表
(while
(and (setq SysNam (car *Old_SysVar*))
(setq SysVar (cadr *Old_SysVar*))
)
(setq *Old_SysVar* (cddr *Old_SysVar*))
(setvar SysNam SysVar)
)
);恢复
(setq *error* *OldEr*)
(or (wcmatch (strcase Msg) "*BREAK,*CANCEL*,*EXIT*")
(princ (strcat "\n** Error: " Msg " **"))
)
);自定义出错函数 *error*
(if (= 8 (logand (getvar "undoctl") 8))
(command "_undo" "_e")
);如果有活动编组,先结束编组
(command "_undo" "_be")
(if SysLst
(while
(and (setq SysNam (car SysLst))
(setq SysVar (cadr SysLst))
)
(setq *Old_SysVar* (append *Old_SysVar* (list SysNam (getvar SysNam))));储存系统变量
(setq SysLst (cddr SysLst))
(setvar SysNam SysVar);设置系统变量
)
)
(princ)
)
;;;例4:自定义通用错误处理恢复函数
(defun Gxl-ErrEnd ();恢复参数
(if (= 8 (logand (getvar "undoctl") 8))
(command "_undo" "_e")
);如果有活动编组,先结束编组
(if *OldEr*
(setq *error* *OldEr*
*OldEr* nil
);恢复参数函数
)
(if *Old_SysVar* ;恢复储存的系统变量
(while
(and (setq SysNam (car *Old_SysVar*))
(setq SysVar (cadr *Old_SysVar*))
)
(setq *Old_SysVar* (cddr *Old_SysVar*))
(setvar SysNam SysVar)
)
)
(setq *DoFun* nil
*UnMde* nil
)
(princ)
)
;;;实际运用示例:
(defun C:TT ()
(Gxl-ErrStaSys '("osmode" 0 "cmdecho" 0 "cecolor" "1"));记录参数
;;主程序内容
.
.
(Gxl-ErrEnd);恢复参数
(princ)
)
(Gxl-ErrStaSys SysLst)错误处理函数,当程序运行出错时只可以对保存的系统变量进行恢复
但这在复杂的程序面前,并不能满足我们的需要,因为各种各样的程序在运行出错后可能还要进行其他各种各样不同的处理
为此,我们要对 Gxl-ErrStaSys 函数进行进一步改进,使得 Gxl-ErrStaSys 函数可以应对各种可能出现的各种问题。
;;;例5:改进后的自定义通用错误处理初始化函数
(defun Gxl-ErrSta (SysLst DoFun UnMde / SysNam SysVar)
;|(Gxl-ErrSta SysLst DoFun UnMde)
功能: 多功能错误处理函数
参数:
SysLst = 系统变量表
DoFun = 要执行的函数 ,无动作则为nil
UnMde = Undo处理模式 0 = 不编组 1 = 仅仅编组 2 = 回到出错前
|;
(setq *OldEr* *error*
*DoFun* DoFun
*UnMde* UnMde
)
(defun *error* (Msg / SysNam SysVar)
(if (= 2 *UnMde*)
(progn
(if (= 8 (logand (getvar "undoctl") 8))
(command "_undo" "_e")
);如果有活动编组,先结束编组
(command "_U")
)
(progn
(if *Old_SysVar*
(while
(and (setq SysNam (car *Old_SysVar*))
(setq SysVar (cadr *Old_SysVar*))
)
(setq *Old_SysVar* (cddr *Old_SysVar*))
(setvar SysNam SysVar)
)
)
(if *DoFun* (vl-catch-all-apply *DoFun*));执行函数
(if (= *UnMde* 1)
(if (= 8 (logand (getvar "undoctl") 8))
(command "_undo" "_e")
);如果有活动编组,先结束编组
)
)
)
(setq *error* *OldEr*
*OldEr* nil
*DoFun* nil
*UnMde* nil
)
(or (wcmatch (strcase Msg) "*BREAK,*CANCEL*,*EXIT*")
(princ (strcat "\n** Error: " Msg " **"))
)
)
(if (or (= *UnMde* 1) (= *UnMde* 2))
(progn
(if (= 8 (logand (getvar "undoctl") 8))
(command "_undo" "_e")
);如果有活动编组,先结束编组
(command "_undo" "_BE");编组开始
)
)
(if SysLst
(while
(and (setq SysNam (car SysLst))
(setq SysVar (cadr SysLst))
)
(setq *Old_SysVar* (append *Old_SysVar* (list SysNam (getvar SysNam))))
(setq SysLst (cddr SysLst))
(setvar SysNam SysVar)
)
)
(princ)
)
;;;错误处理应用范例:
(defun C:TT (/ ErrFun p1 p2 p3)
;初始化*error* 参数UnMde根据需要可设置为 0 1 2
(Gxl-ErrSta (list 'blipmode 0 'cmdecho 0 'osmode 0) 'ErrFun 2);出错只编组
(defun ErrFun () ;出错后*error*要执行的动作
(alert "出错啦！")
)
(setq p1 (getpoint "\n第一点: "))
(setq p2 (getpoint "\n第二点: "))
(setq p3 (getpoint "\n第三点: "))
(vl-cmdf "line" p1 p2 p3 "c")
;将UnMde分别设置为 0 1 2,运行到以下任意位置按下ESC试试效果
(setq p1 (getpoint "\n第一点: "))
(setq p2 (getpoint "\n第二点: "))
(setq p3 (getpoint "\n第三点: "))
(vl-cmdf "line" p1 p2 p3 "c")
(setq p1 (getpoint "\n第一点: "))
(setq p2 (getpoint "\n第二点: "))
(setq p3 (getpoint "\n第三点: "))
(vl-cmdf "line" p1 p2 p3 "c")
(setq p1 (getpoint "\n第一点: "))
(setq p2 (getpoint "\n第二点: "))
(setq p3 (getpoint "\n第三点: "))
(vl-cmdf "line" p1 p2 p3 "c")
(Gxl-ErrEnd)
(princ)
)
可能有些读者觉得对于这样的出错处理函数中,对于系统变量表参数,要写一长串变量,也很麻烦
因为在程序中,我们经常要设置和使用的一些系统变量都数量有限。为此,我们提供另外一种错误处理的方法和思路
在初始化错误函数中保存一些常用的系统变量初始值,储存在全局变量中,然后初始化一些常用系统变量的值
程序中可以对这些已经保存的系统变量任意修改,在程序结束时用错误恢复函数自动恢复系统变量值,程序出错时由错误处理函数来恢复系统变量值。
我们将一些有关经常使用的系统变量名储存表,设为常量 *SNLst* :
(setq *SNLst* (list 'AUNITS 'AUPREC 'ATTDIA 'ATTREQ 'BLIPMODE 'DIMZIN 'CECOLOR
'CELTYPE 'CLAYER 'CMDECHO 'TRIMMODE 'EXPERT 'HIGHLIGHT 'LUNITS
'LUPREC 'EDGEMODE 'OSMODE 'ORTHOMODE 'TEXTSTYLE 'PLINEWID 'PLINEGEN
'FILEDIA 'PICKBOX 'QAFLAGS 'UCSAXISANG 'CELTSCALE 'NOMUTT
'PEDITACCEPT 'Mirrtext 'limcheck
)
);*SNLst* 常用系统变量表
;;;例6、自定义通用错误处理函数Gxl-ErrSta02:
(defun Gxl-ErrStaNrm (DoFun UnMde)
;|自定义错误处理函数 Gxl-ErrStaNrm
参数:
DoFun = 要执行的函数,无动作则为nil
UnMde = Undo处理模式 0 = 不编组 1 = 仅仅编组 2 = 回到出错前
|;
(defun *error* (Msg / SysNam SysVar)
(if (= 2 *UnMde*)
(progn
(if (= 8 (logand (getvar "undoctl") 8))
(command "_undo" "_e")
);如果有活动编组,先结束编组
(command "_U")
)
(progn
(if *DoFun* (vl-catch-all-apply *DoFun*));执行函数
(if (= *UnMde* 1)
(if (= 8 (logand (getvar "undoctl") 8))
(command "_undo" "_e")
);如果有活动编组,先结束编组
)
)
)
(if (and *SVLst* *SNLst*)
(mapcar
'(lambda (a b)
(vl-catch-all-apply 'setvar (list a b))
)
*SNLst*
*SVLst*
)
);回收变量值
(setq *error* *OldEr*
*OldEr* nil
*DoFun* nil
*UnMde* nil
*SVLst* nil
)
(or (wcmatch (strcase Msg) "*BREAK,*CANCEL*,*EXIT*")
(princ (strcat "\n** Error: " Msg " **"))
)
);定义出错函数
;程序开始
(setq *SVLst* nil);*SVLst* 用于储存系统变量表 *SNLst* 中系统变量对应的值
(setq *SVLst* (mapcar '(lambda (x) (getvar x)) *SNLst*))
;对一些程序中必须要初始化为0的系统变量初始化为0
(foreach XX '("ATTDIA" "ATTREQ" "BLIPMODE" "CMDECHO" "DIMZIN" "OSMODE" "ORTHOMODE" "MIRRTEXT")
(setvar XX 0)
)
(setq *OldEr* *error*
*DoFun* DoFun
*UnMde* UnMde
)
(if (or (= *UnMde* 1) (= *UnMde* 2))
(progn
(if (= 8 (logand (getvar "undoctl") 8))
(command "_undo" "_e")
);如果有活动编组,先结束编组
(command "_undo" "_BE")
)
);是否开始编组
;| EXPERT = 5 禁止显示提示
"块已经存在。重新定义？"
使用DIMSTYLE 命令的"保存"选项时,如果输入的标注样式名已经存在,系统将显示该提示。
如果 EXPERT 禁止显示一个提示,相应操作会认为用户已输入 y 确认提示。
EXPERT 的设置会影响脚本、菜单宏、AutoLISP 及其命令函数。
|;
(setvar "EXPERT" 5)
(setvar "CECOLOR" "BYLAYER");设置颜色随层
(setvar "celtype" "BYLAYER");设置线型随层
(setvar "LWDISPLAY" 1);设置显示线宽
(setvar "CELTSCALE" 1);设置当前线形比例为1
(setvar "PLINEGEN" 1);设置围绕多段线顶点生成连续线型
)
;;;例7:Gxl-ErrSta02对应的自定义通用错误处理恢复函数
(defun Gxl-ErrEndNrm ()
(if (or (= *UnMde* 1) (= *UnMde* 2))
(if (= 8 (logand (getvar "undoctl") 8))
(command "_undo" "_e")
);如果有活动编组,先结束编组
)
(if *OldEr*
(setq *error* *OldEr*
*OldEr* nil
);恢复参数函数
)
(if (and *SVLst* *SNLst*)
(mapcar
'(lambda (a b)
(vl-catch-all-apply 'setvar (list a b))
)
*SNLst*
*SVLst*
)
)
(setq *DoFun* nil
*UnMde* nil
*SVLst* nil
)
)(princ)
;;;错误处理应用示例:
(defun C:TT (/ ErrFun p1 p2 p3)
;;初始化*error* 参数UnMde根据需要可设置为 0 1 2
(Gxl-ErrStaNrm 'ErrFun 2);出错只编组,这里省去了系统变量设置
(defun ErrFun ();出错后*error*要执行的动作
(alert "出错啦！")
)
(setq p1 (getpoint "\n第一点: "))
(setq p2 (getpoint "\n第二点: "))
(setq p3 (getpoint "\n第三点: "))
(vl-cmdf "line" p1 p2 p3 "c")
;;将 UnMde分别设置为 0 1 2,运行到以下任意位置按下ESC试试效果
(setq p1 (getpoint "\n第一点: "))
(setq p2 (getpoint "\n第二点: "))
(setq p3 (getpoint "\n第三点: "))
(vl-cmdf "line" p1 p2 p3 "c")
(setq p1 (getpoint "\n第一点: "))
(setq p2 (getpoint "\n第二点: "))
(setq p3 (getpoint "\n第三点: "))
(vl-cmdf "line" p1 p2 p3 "c")
(setq p1 (getpoint "\n第一点: "))
(setq p2 (getpoint "\n第二点: "))
(setq p3 (getpoint "\n第三点: "))
(vl-cmdf "line" p1 p2 p3 "c")
(Gxl-ErrEndNrm)
(princ)
)
//三、Vl-Catch-All-Apply函数捕捉错误的应用技巧
上面部分讨论的是传统的*error*方法,这种方法是对整个程序设置的统一的处理功能
无论程序中什么地方出错,都集中在这里处理！这种情况在程序比较简单,要处理的情况不多时,比较容易应付,因为这时程序需要处理的情况比较少！
当程序的规模比较大,要处理的情况比较复杂时,就很难满足我们对程序错误处理的要求,特别是当出现同样的错误代码需要在程序的不同部分做出不同处理的时候。
幸运的是,AutoLisp另外还提供了三个错误处理函数。
Vl-Catch-All-Apply函数能够捕捉指定函数的错误
Vl-Catch-All-Apply-Error-Message函数可以读取相关错误信息
Vl-Catch-All-Error-P函数可以测试Vl-Catch-All-Apply函数返回结果是否异常。
;;;例如:下面这个函数是根据图上选取直角三角形的一条直角边,然后输入斜边长度,根据勾股定理计算另一直角边,并绘制三角形的例子:
(defun C:TT (/ p1 p2 d1 dd Ang)
;初始化错误处理,出错后回到初始状态
(Gxl-ErrSta (list "cmdecho" 0 "osmode" 0) nil 2)
(setq p1 (getpoint "\n输入直角三角形直角边第一点: "))
(setq p2 (getpoint p1 "\n输入直角三角形直角边第二点: "))
(setq d1 (distance p1 p2))
(vl-cmdf "_line" p1 p2 "")
(setq dd (getdist p1 "\n请输入斜边长度: "))
;;根据勾股定理计算另一条直角边长度
(setq d2 (vl-catch-all-apply ;捕捉 sqrt 函数的错误
'sqrt
(list
(- (* dd dd) (* d1 d1))
)
)
)
(if (vl-catch-all-error-p d2);当输入的斜边长度小于直角边长度时 sqrt 函数会出错
(progn ;sqrt 函数结果异常
(alert (vl-catch-all-error-message d2));提示错误信息
(abcdefg);自己的错误退出程序
)
(progn
(setq Ang (+ (angle p1 p2) (* 0.5 pi)))
(command "_line" p2 (polar p2 angd2) p1 "")
);绘制三角形
)
(Gxl-ErrEnd);恢复错误处理
(princ)
)
这样,自定义函数test就可以返回正确的结果或出错信息这两种结果,这是一种新的函数定义模式
其使用方法简而言之就是使用Vl-Catch-All-Apply对函数进行包装,然后使用Vl-Catch-All-Error-P判断包装函数返回值是否异常
若有异常,可使用Vl-Catch-All-Apply-Error-Message函数输出错误信息,并再此对错误进行处理。

复制代码

admin · 发表于 2024-4-6 16:40:58

Gxl-ErrStaSys -> Gxl-ErrEnd ;只针对系统变量的恢复
Gxl-ErrSta -> Gxl-ErrEnd ;系统变量+函数+编组
Gxl-ErrStaNrm -> Gxl-ErrEndNrm ;只针对自定义常量的恢复
(if (null vlax-dump-object) (vl-load-com));将Visual LISP扩展功能加载到 AutoLISP
(defun C:TT (/ *error* CurDoc *Old_SysVar*)
(setq CurDoc (vla-get-activedocument (vlax-get-acad-object)))
(defun *error* (x) ;出错函数
;其它需要恢复的内容
(if *Old_SysVar* (foreach xx *Old_SysVar* (apply 'setvar xx)));参数恢复
(vla-endundomark CurDoc) ;错误时结束编组
)
(while (eq 8 (logand 8 (getvar 'undoctl)))
(vla-endundomark CurDoc)
) ;关闭以前的编组
(vla-startundomark CurDoc) ;记录编组
(progn ;记录系统变量
(setq *Old_SysVar* '());清空变量,避免出错
(setq *Old_SysVar*
(mapcar
'(lambda (a / b)
(if (setq b (getvar (car a)))
(progn
(vl-catch-all-apply 'setvar a)
(list (car a) b)
)
)
)
(list
(list "DIMZIN" 0);保留前导和后续的零
(list "CMDECHO" 0) ;关闭回显
)
)
);记录参数
)
;你的程序
(command "redraw");清空一行
(if *Old_SysVar* (foreach xx *Old_SysVar* (apply 'setvar xx)));参数恢复
(vla-endundomark CurDoc) ;结束编组
(princ)
)

复制代码

		自动登录	找回密码
密码			立即注册